Danh sách top được sử dụng để xếp hạng các công ty hoặc cá nhân dựa trên các giá trị. Xếp hạng này được thiết lập dựa trên hiệu suất, chất lượng, v.v. hoặc các tiêu chí khác. Trong bài viết này, chúng ta sẽ học cách tạo danh sách Top 10 động trong Excel.
8 Phương Pháp Tạo Danh Sách Top 10 Động Trong Excel
Chúng ta sẽ thảo luận về một số phương pháp để tạo danh sách Top 10 Động trong Excel. Danh sách top 10 đưa ra ý tưởng về các tên hàng đầu trong các lĩnh vực nhất định.
Chúng tôi đã lấy một tập dữ liệu chứa điểm số của sinh viên tại đây. Bây giờ, chúng ta sẽ tạo một danh sách Top 10 Động sử dụng tập dữ liệu này.
1. Hàm LARGE Trong Excel Để Tạo Danh Sách Top 10
Hàm LARGE tìm số lớn thứ k từ một phạm vi cho trước.
Chúng ta thiết lập 1-10 số thứ tự trên tập dữ liệu dưới đây.
Đầu tiên, chúng ta sẽ tìm ra top 10 điểm cao nhất và sau đó lấy tên sinh viên.
Bước 1:
- Chúng ta sẽ áp dụng kết hợp công thức của hàm LARGE và ROW.
- Đi đến Ô G5 và đặt công thức dưới đây.
=LARGE($C$5:$C$18,ROW(F5)-ROW($F$4))
Bước 2:
- Nhấn nút Enter và kéo biểu tượng Fill Handle (Cán Kéo Điền).
Chúng ta nhận được top 10 điểm. Chúng ta cũng có thể sử dụng hàm ROWS cho mục đích này.
Công Thức Thay Thế:
Chúng ta có thể sử dụng công thức thay thế để có cùng kết quả.
Các Bước:
- Sử dụng công thức sau trong Ô G5:
=LARGE($C$5:$C$18,ROWS(C$5:C5))
- Nhấn Enter và kéo Fill Handle hết chỗ.
Bây giờ, nếu bạn muốn hiển thị tên tương ứng của danh sách top 10, hãy làm như sau.
Các Bước:
- Đi đến Ô F5 và đặt công thức sau.
=INDEX($B$5:$B$18,MATCH(G5,$C$5:$C$18,0))
- Nhấn Enter và kéo biểu tượng Fill Handle.
Ở đây, chúng ta nhận được top 10 tên kèm theo điểm số của họ.
2. Kết Hợp Hàm INDEX, MATCH Và LARGE Để Tạo Danh Sách Top 10
Trong phần này, chúng ta sẽ sử dụng kết hợp của các hàm INDEX, MATCH, và LARGE. Chúng ta sẽ trực tiếp lấy top 10 tên bằng phương pháp này.
Bước 1:
- Đi đến Ô F5.
- Đặt công thức sau vào ô đó.
=INDEX($B$5:$B$18,MATCH(LARGE($C$5:$C$18,E5),$C$5:$C$18,0))
Bước 2:
- Nhấn nút Enter và kéo biểu tượng Fill handle.
Ở đây, chúng ta trực tiếp nhận được top 10 tên mà không cần sự giúp đỡ của cột khác.
Phân Tích Công Thức:
- LARGE($C$5:$C$18,E5) - Nó tạo ra số lớn nhất từ phạm vi dựa trên giá trị của Ô E5. Kết quả: 96
- MATCH(LARGE($C$5:$C$18,E5),$C$5:$C$18,0) - Nó đại diện cho số lượng kết quả sẽ được hiển thị. Kết quả: 10
- INDEX($B$5:$B$18,MATCH(LARGE($C$5:$C$18,E5),$C$5:$C$18,0)) - Điều này hiển thị top 10 kết quả từ phạm vi. Kết quả: {Jose, Henderson, Gerg, Josef, Aaron, Jose, Jessica, Joe, Rogers, Allisa}
3. Sử Dụng Công Thức Mảng Để Tạo Danh Sách Top 10 Động Trong Excel
Chúng ta sẽ sử dụng công thức mảng cho phương pháp này. Cả top 10 tên và điểm số của sinh viên sẽ hiển thị sau khi áp dụng công thức này. Công thức này là kết hợp của các hàm INDEX, SORT, và SEQUENCE.
Bước 1:
- Đi đến Ô F5.
- Sao chép và dán công thức dưới đây.
=INDEX(SORT(B5:C18,2,-1),SEQUENCE(10),{1,2})
Bước 2:
- Nhấn nút Enter và kéo biểu tượng Fill Handle.
Chúng ta nhận được cả tên và điểm số chỉ bằng cách áp dụng công thức. Không cần kéo công thức.
Phân Tích Công Thức:
- SEQUENCE(10) - Nó cho một dãy số từ 1 đến 10. Kết quả: {1,2,3,4,5,6,7,8,9,10}
- SORT(B5:C18,2,-1) - Nó sắp xếp dữ liệu dựa trên cột thứ hai. Kết quả: {Jose 96, Henderson 95, Gerg 89, Josef 84, Aaron 80, Jose 71, Jessica 70, Joe 65, Rogers 61, Allisa 60, Joe 57, Allisa 49, John 45, Mitchel 40}
- INDEX(SORT(B5:C18,2,-1),SEQUENCE(10),{1,2}) - Nó cho danh sách top ten đã sắp xếp. Kết quả: {Jose 96, Henderson 95, Gerg 89, Josef 84, Aaron 80, Jose 71, Jessica 70, Joe 65, Rogers 61, Allisa 60}
4. Áp Dụng Hàm XLOOKUP Của Excel Để Thiết Kế Danh Sách Top 10
Hàm XLOOKUP tìm kiếm đối tượng từ một phạm vi hoặc mảng cho trước và đưa ra kết quả dựa trên sự khớp.
Chúng ta sẽ sử dụng kết hợp của hàm XLOOKUP và LARGE trong phần này. Chúng ta chỉ muốn lấy danh sách top 10 tên tại đây.
Bước 1:
- Đi đến Ô F5 và đặt công thức sau.
=XLOOKUP(LARGE($C$5:$C$18,E5),$C$5:$C$18,$B$5:$B$18)
Bước 2:
- Nhấn nút Enter.
- Sau đó, kéo biểu tượng Fill Handle.
5. Kết Hợp Hàm SORT Và FILTER Để Xây Dựng Danh Sách Top 10
Hàm FILTER cho phép lọc một phạm vi giá trị từ tiêu chí cho trước của chúng ta.
Trong phần này, chúng ta sẽ kết hợp các hàm SORT và FILTER với hàm LARGE để lấy danh sách top 10 trong Excel.
Bước 1:
- Đi đến Ô F5.
- Đặt công thức sau.
=SORT(FILTER(B5:C18,C5:C18>=LARGE(C5:C18,10)),2,-1)
Bước 2:
- Bây giờ, chỉ cần nhấn nút Enter.
Chúng ta nhận được cả tên và điểm của sinh viên bằng cách áp dụng phương pháp này.
Đọc Thêm: Cách Tạo Danh Sách Động Trong Excel Dựa Trên Tiêu Chí (Tiêu Chí Đơn Và Nhiều Tiêu Chí)
6. Thiết Kế Danh Sách Top 10 Động Cho Dữ Liệu Trùng Lặp
Khi chúng ta có dữ liệu trùng lặp, chúng ta có thể sử dụng phương pháp này để thiết kế danh sách top 10 trong Excel.
Bước 1:
- Đi đến Ô F5.
- Đặt công thức dưới đây vào ô đó.
=INDEX($B$5:$B$18, MATCH(1, ($C$5:$C$18=LARGE($C$5:$C$18, E5)) * (COUNTIF(F$4:F4, $B$5:$B$18)=0), 0))
Bước 2:
- Nhấn nút Enter.
Chúng ta chỉ nhận được tên của sinh viên ở đây.
7. Định Dạng Có Điều Kiện, Bộ Lọc, Và Công Cụ Sắp Xếp Để Tạo Danh Sách Top 10 Động
Chúng ta có thể kết hợp nhiều công cụ để lấy danh sách top 10. Đó là Định Dạng Có Điều Kiện (Conditional Formatting), Bộ Lọc (Filter), và Sắp Xếp (Sort).
Bước 1:
- Chọn Ô C5 đến C18.
- Nhấp Định Dạng Có Điều Kiện từ thanh Ribbon.
- Chọn Top 10 Items từ Top/Bottom Rules.
Bước 2:
- Một hộp thoại sẽ xuất hiện. Chú ý 10, vì top 10.
- Sau đó, nhấn OK.
Bước 3:
- Chọn Ô C4 đến C18.
- Nhấn nút chuột phải.
- Chọn Lọc Theo Màu Ô Đã Chọn (Filter by Selected Cell's Color) từ danh sách Bộ Lọc (Filter).
Bước 4:
- Nhấp tùy chọn Lọc Theo Màu (Filter by Color).
Đây là dữ liệu top 10. Bây giờ chúng ta sẽ sắp xếp chúng.
Bước 5:
- Lại nhấn nút chuột phải.
- Chọn Sắp Xếp Từ Lớn Đến Nhỏ (Sort Largest to Smallest) từ danh sách Sắp Xếp (Sort).
Bước 6:
- Chọn Mở Rộng Lựa Chọn (Expand the selection).
- Sau đó nhấn Sắp Xếp (Sort).
Bây giờ, dữ liệu top 10 của chúng ta đã được sắp xếp tốt.
Đọc Thêm: Cách Tạo Danh Sách Xác Thực Dữ Liệu Động Sử Dụng VBA Trong Excel
8. Tạo Danh Sách Top 10 Trong Excel Sử Dụng Bảng Pivot (Pivot Table)
Chúng ta sẽ hình thành danh sách top 10 trong Excel sử dụng Bảng Pivot.
Bước 1:
- Đi đến tab Chèn (Insert).
- Sau đó chọn Từ Bảng/Phạm Vi (From Table/Range) từ danh sách PivotTable.
Bước 2:
- Chọn phạm vi của chúng ta từ tập dữ liệu.
- Sau đó, nhấn OK.
Bước 3:
- Đánh dấu vào Tên (Name) và Điểm (Mark) của Các Trường PivotTable (PivotTable Fields).
Bước 4:
- Bây giờ, đi đến Nhãn Hàng (Row Labels).
- Chọn Top 10 từ Bộ Lọc Giá Trị (Value Filters).
Bước 5:
- Một hộp thoại sẽ xuất hiện. Nhấp OK trên hộp đó.
Danh sách top 10 của chúng ta ở đây. Nhưng dữ liệu ở dạng chưa sắp xếp.
Đọc Thêm: Excel Tạo Danh Sách Động Từ Bảng (3 Cách Dễ Dàng)
Kết Luận
Trong bài viết này, chúng ta đã thảo luận cách tạo danh sách top 10 động trong Excel. Tôi hy vọng điều này sẽ đáp ứng nhu cầu của bạn. Vui lòng xem trang web Exceldemy.com của chúng tôi và đưa ra góp ý trong hộp bình luận.
Các Bài Viết Liên Quan
- Tạo Danh Sách Thả Xuống Động Sử Dụng Excel OFFSET (3 Cách)
- Cách Tạo Danh Sách Thả Xuống Động Sử Dụng VBA Trong Excel