Hàm DATE trong Excel kết hợp ba giá trị để tạo một ngày tháng. Khi bạn chỉ định năm, tháng và ngày, Excel tạo ra một số thứ tự (serial number) sau đó có thể định dạng thành ngày tháng bình thường.
Cách điển hình để nhập ngày trong Excel là viết toàn bộ ngày trong một ô, nhưng điều đó bất tiện khi bạn xử lý nhiều thông tin. Hàm DATE có thể hữu ích nếu ngày tháng không được định dạng đúng, ví dụ như nó kết hợp với văn bản thông thường hoặc trải dài trên nhiều ô.
Hàm DATE khá dễ hiểu và nhớ. Dưới đây là thêm thông tin về cách sử dụng nó trong công thức của bạn.
Hàm DATE có thể dùng trong mọi phiên bản Excel.
Cú pháp và đối số của hàm DATE
Mọi trường hợp của hàm DATE đều phải được viết như sau để Excel xử lý đúng:
=DATE(năm, tháng, ngày)
- Năm (Year): Nhập năm dưới dạng số có từ 1 đến 4 chữ số hoặc nhập tham chiếu ô đến vị trí dữ liệu trong trang tính. Đối số năm là bắt buộc.
- Tháng (Month): Nhập tháng trong năm dưới dạng số nguyên dương hoặc âm từ 1 đến 12 (Tháng 1 đến Tháng 12) hoặc nhập tham chiếu ô đến vị trí dữ liệu. Đối số tháng là bắt buộc.
- Ngày (Day): Nhập ngày trong tháng dưới dạng số nguyên dương hoặc âm từ 1 đến 31 hoặc nhập tham chiếu ô đến vị trí dữ liệu. Đối số ngày là bắt buộc.
Thông tin bổ sung về hàm DATE
Dưới đây là những điều quan trọng khác về các đối số năm, tháng và ngày:
NĂM (YEAR)
- Mặc định, Excel sử dụng hệ ngày 1900, nghĩa là hàm DATE sẽ không hiển thị năm chính xác cho bất kỳ năm nào trước năm 1900.
- Nhập 0 làm giá trị năm tương đương với nhập 1900, 1 bằng 1901, 105 là 2005, v.v.
THÁNG (MONTH)
- Vượt quá 12 làm giá trị tháng sẽ thêm số tháng đó vào giá trị năm. 13 sẽ thêm một năm và một tháng vào ngày tháng.
- Sử dụng số âm làm giá trị tháng sẽ trừ số tháng đó, cộng thêm một, từ tháng đầu tiên của năm.
NGÀY (DAY)
- Nếu giá trị ngày vượt quá số ngày của tháng đó, các ngày dư sẽ được cộng vào ngày đầu tiên của tháng tiếp theo.
- Giá trị ngày âm sẽ trừ số ngày đó, cộng thêm một, từ ngày đầu tiên của tháng.
Ví dụ hàm DATE
Dưới đây là một số công thức thực tế sử dụng hàm DATE:
Năm, Tháng, Ngày ở các ô khác
=DATE(A2,B2,C2)
Ví dụ này của hàm DATE sử dụng A2 cho năm, B2 cho tháng, và C2 cho ngày.
Năm trong công thức, Tháng và Ngày ở ô khác
=DATE(2020,A2,B2)
Bạn cũng có thể kết hợp cách lấy dữ liệu. Trong ví dụ này, chúng ta đặt 2020 làm đối số năm, nhưng tháng và ngày được lấy từ các ô khác.
Trừ tháng bằng đối số Tháng âm
=DATE(2020,-2,15)
Ở đây, chúng ta dùng số âm ở vị trí tháng. Điều này lùi ngược qua năm thay vì tiến tới, bắt đầu từ Tháng 1 năm 2020 (vì công thức có 2020). Công thức DATE này tạo ra 15/10/2019.
Trừ ngày bằng đối số Ngày âm
=DATE(2020,1,-5)
Nếu không có số âm, ngày này sẽ được tính là 5/1/2020. Tuy nhiên, giá trị ngày âm trừ đi năm ngày (cộng một) từ 1/1/2020, tạo ra ngày 26/12/2019.
Đối số Ngày và Tháng lớn
=DATE(2020,19,50)
Ví dụ này kết hợp một vài quy tắc trên. Giá trị năm sẽ tăng từ 2020 vì tháng vượt quá 12, và tháng được tính cũng sẽ thay đổi vì giá trị ngày vượt quá số ngày của bất kỳ tháng nào. Công thức DATE này tạo ra 19/8/2021.
Thêm 10 năm vào ngày trong ô khác
=DATE(YEAR(A2)+10,MONTH(A2),DAY(A2))
Hàm DATE trong Excel cũng có thể dùng với các ngày khác, như thêm thời gian vào ngày hiện có. Trong ví dụ này, chúng ta muốn xem ngày sau 10 năm so với ngày hiện có. Ngày hiện có ở ô E2, vì vậy chúng ta cần viết công thức trích xuất năm, tháng, ngày từ E2 nhưng cũng cộng 10 vào giá trị năm.
Tính số ngày trong năm
=A2-DATE(YEAR(A2),1,0)
Đây là ví dụ tương tự của hàm DATE nơi chúng ta tính xem ngày trong ô E10 là ngày thứ bao nhiêu trong năm. Ví dụ, 1/1/2020 là ngày đầu tiên trong năm, 5/1 là ngày thứ năm, v.v. Trong ví dụ này, E10 là 4/8/2018, nên kết quả là 216.
Chuyển đổi ngày dạng văn bản thành ngày định dạng đúng
=DATE(LEFT(A2,4),MID(A2,5,2),RIGHT(A2,2))
Nếu ô bạn đang xử lý chứa ngày đầy đủ nhưng định dạng là văn bản, như 20200417, bạn có thể dùng công thức DATE này, kết hợp với hàm LEFT, MID và RIGHT, để chuyển ô thành ngày định dạng đúng.
Công thức này trích xuất 4 chữ số đầu từ bên trái bằng LEFT(A2,4), lấy 2 chữ số từ giữa bắt đầu ở ký tự thứ 5 qua MID(A2,5,2), và kết hợp với 2 chữ số cuối từ bên phải bằng RIGHT(A2,2). Ngày tính được là 17/4/2020.
Xem bài viết của chúng tôi về cách dùng hàm LEFT, RIGHT, và MID trong Excel để biết thêm chi tiết.
Năm và Tháng năm nay, Ngày cụ thể
=DATE(YEAR(TODAY()), MONTH(TODAY()), 5)
Hàm TODAY có thể dùng với hàm DATE để lấy thông tin về hôm nay. Ví dụ, để nhắc bản thân thanh toán hóa đơn hàng tháng vào ngày 5, bạn có thể dùng công thức DATE này để tự động thêm năm và tháng hiện tại, nhưng đặt 5 (hoặc tham chiếu ô) làm giá trị ngày.
Tính ngày khi Tháng là văn bản
=DATE(A2,MONTH(1&B2),C2)
Đôi khi ngày tháng bao gồm dạng văn bản của tháng, như Tháng Sáu. Vì Excel không hiểu đây là số, bạn phải chuyển đổi nó sang số bằng hàm MONTH. Chúng ta đã nhúng trực tiếp vào công thức DATE, ở vị trí tháng, là MONTH(1&B2).
Sửa ngày không trông như ngày
Nếu kết quả của hàm DATE hiển thị một dãy số thay vì ngày tháng, bạn sẽ cần định dạng ô thành ngày.
Ví dụ, bạn có thể thấy một số lớn như 43938 thay vì ngày tháng bình thường, như trong ảnh chụp màn hình dưới đây:
Để định dạng lại ô, hãy chọn nó, chọn menu thả xuống từ mục Số (Number), rồi chọn một trong các định dạng ngày.