Đếm ký tự trong ô Excel dễ dàng hơn bạn nghĩ. Với vài công thức đơn giản, bạn đếm được số ký tự trong một ô, nhiều ô, thậm chí tổng ký tự cụ thể.
Dù chuẩn bị xuất dữ liệu cần giới hạn ký tự/ô, hay muốn tìm số lần xuất hiện ký tự đặc biệt, đây là cách làm trong Microsoft Excel.
Đếm ký tự trong một ô đơn lẻ
Để lấy tổng ký tự trong ô, dùng hàm LEN của Excel. Cú pháp: LEN(ô), nhập tham chiếu ô cho đối số.
Ví dụ, đếm ký tự ô A2 bằng công thức:
=LEN(A2)
Nhớ rằng dấu câu, khoảng trắng đều tính là ký tự, kể cả khoảng trắng sau ký tự cuối cùng trong chuỗi.
Mẹo: Bạn cũng đếm số byte trong ô bằng hàm LENB. Ví dụ: =LENB(A2) cho ví dụ trên.
Có thể bạn muốn số ký tự trong nhiều ô. Dùng hàm LEN cộng với hàm SUM.
Ví dụ, công thức sau đếm ký tự trong ô A2, A4, A6:
=SUM(LEN(A2),LEN(A4),LEN(A6))
Đếm ký tự trong phạm vi ô (Cell Range)
Muốn tổng ký tự trong nhiều ô liền kề, bạn liệt kê từng tham chiếu ô như công thức trên, nhưng có cách tốt hơn. Vẫn dùng LEN và SUM để đếm ký tự trong phạm vi ô.
Ví dụ, lấy số ký tự ô A2 đến A4 bằng công thức:
=SUM(LEN(A2:A4))
Như bạn thấy, chỉ cần thêm phạm vi ô trong phần LEN của công thức để ra tổng.
Mẹo: Nếu quen hàm SUMPRODUCT, dùng nó thay SUM cho cùng kết quả. Ví dụ: =SUMPRODUCT(LEN(A2:A4)).
Nhiều phạm vi ô
Đếm ký tự trong hai phạm vi khác nhau, tiếp tục dùng SUM và LEN.
Ở đây, lấy số lượng ô A2:A4 cộng C2:C4 bằng công thức:
=SUM(LEN(A2:A4),LEN(C2:C4))
Trong trường hợp này, chỉ cần thêm cả hai công thức LEN vào trong ngoặc của hàm SUM.
Đếm ký tự cụ thể trong ô
Có thể bạn cần đếm số lần xuất hiện ký tự cụ thể. Lúc này dùng LEN kết hợp SUBSTITUTE.
Ví dụ, đếm số chữ L trong ô A1. Dùng công thức:
=LEN(A2)-LEN(SUBSTITUTE(A2,"L",""))
Kết quả 1 đúng. Phân tích cấu trúc công thức từ trong ra ngoài:
- SUBSTITUTE(A2,"L","") thay thế tất cả chữ L bằng chuỗi rỗng trong ô A2.
- LEN(SUBSTITUTE(A2,"L","")) đếm ký tự ô A2 (không có chữ L).
- LEN(A2) đếm tổng ký tự ô A2.
- LEN(A2)-LEN(SUBSTITUTE(A2,"L","")) trừ số ký tự (không có L) từ tổng ký tự ô A2.
Đếm ký tự cụ thể bỏ qua chữ hoa/thường
Như bạn thấy, công thức trên chỉ cho 1 chữ L. Vì công thức chứa L in hoa, không tìm chữ thường.
Để xử lý phân biệt hoa/thường, thêm UPPER hoặc LOWER vào SUBSTITUTE. Tóm lại, thay thế tất cả lần xuất hiện, bất kể hoa thường, bằng chuỗi rỗng.
Dùng cùng ví dụ, thêm UPPER như sau:
=LEN(A2)-LEN(SUBSTITUTE(UPPER(A2),"L",""))
Lần này kết quả 3, bao gồm cả L hoa và thường.
Đếm ký tự cụ thể trong phạm vi ô
Muốn áp dụng kiến thức trên đi xa hơn? Phần cuối này chỉ cách đếm ký tự cụ thể trong phạm vi ô. Kết hợp LEN, SUBSTITUTE, SUM.
Với công thức sau, đếm số chữ L trong phạm vi A2:A4:
=SUM(LEN(A2:A4)-LEN(SUBSTITUTE(UPPER(A2:A4),"L","")))
Ở đây, giữ UPPER trong SUBSTITUTE để tìm tất cả chữ L bất kể hoa thường.
Khi bắt đầu dùng các hàm và công thức này trong worksheet, đếm ký tự trong Excel trở nên dễ dàng mỗi lần. Dù lý do gì cần đếm ký tự, hãy để Excel làm việc thay vì đếm thủ công.
Xem thêm hướng dẫn dùng COUNTIFS, SUMIFS, AVERAGEIFS trong Microsoft Excel.