Các bộ phận chính trong ổ đĩa cứng là đĩa quay của chúng và các đầu đọc và ghi dữ liệu trên chúng. Phần bên ngoài của những đĩa hình đĩa đó, nhờ những gì Vật lý dạy cho chúng ta, có gia tốc thẳng nhanh hơn. Ngoài ra, có một chi phí hiệu suất được cảm nhận khi dữ liệu được trải rộng trên toàn bộ bề mặt của chúng.
MyDefrag có thể đã gần tuyệt chủng, nhưng nó vẫn là chương trình duy nhất thuộc loại này có thể tối ưu hóa ổ cứng của bạn theo cách bạn muốn. Giống như tất cả các trình chống phân mảnh, nó tổ chức lại tất cả các phần của tệp của bạn, đóng gói chúng lại với nhau, khắc phục hiệu suất thấp khi lan rộng trên toàn bộ vấn đề trên bề mặt. Nó cũng cho phép bạn thiết lập các vùng, đặt các tệp quan trọng nhất của bạn vào vùng bên ngoài, nhanh hơn của bề mặt ổ cứng. Bạn chỉ cần cho nó biết điều gì sẽ xảy ra thông qua một tập lệnh đơn giản.
Định vị, tải xuống và cài đặt MyDefrag
Thật không may, MyDefrag ngày nay không được hỗ trợ và trang web chính thức của nó đã chết. Tuy nhiên, bạn vẫn có thể tìm thấy nó tại các trang web lưu trữ phần mềm phổ biến như FileHippo và MajorGeeks.
Tải xuống và cài đặt phiên bản mới nhất của chương trình, MyDefrag 4.3.1. Chấp nhận tất cả các giá trị mặc định trong khi cài đặt và đảm bảo rằng “Chọn và kích hoạt MyDefrag ScreenSaver” được bỏ chọn.
Tạo tập lệnh mới
Bạn không kiểm soát cách MyDefrag hoạt động thông qua giao diện đồ họa hoặc các tùy chọn dòng lệnh - điều này được thực hiện với các tập lệnh đơn giản. Xác định vị trí các tập lệnh thư mục con tồn tại cho mục đích này trong thư mục cài đặt của nó.
Nhấp chuột phải vào thư mục này và tạo một tệp TXT trống, mới. Đặt cho nó bất kỳ tên nào bạn vui lòng, nhưng hãy thay đổi phần mở rộng của nó thành “MyD”, mặc định cho các tập lệnh MyDefrag. Sau đó, mở nó trong trình soạn thảo văn bản yêu thích của bạn.
Phần giới thiệu tập lệnh
Chúng tôi sẽ sử dụng những cái hiện có làm cơ sở cho một tập lệnh tối ưu hóa một đĩa cứng chứa đầy trò chơi, đặt các tệp ảnh hưởng đến hiệu suất của chúng nhiều hơn các tệp khác vào các phần nhanh hơn của bề mặt đĩa, di chuyển các tệp ít cần thiết hơn và không thường xuyên- đã truy cập dữ liệu vào đầu bên kia.
Phần đầu tiên của kịch bản của bạn nên thiết lập những thứ như sau. Lưu ý rằng bạn nên đặt mọi tham số và lệnh trên một dòng mới, riêng lẻ. Cũng xin lưu ý rằng chúng tôi sẽ sử dụng các nhận xét trong mã - chúng bắt đầu bằng “//” - để giải thích các bit khó hiểu hơn trong tập lệnh của chúng tôi.
Title("Title of your script")
Description("Short description of your script")
WriteLogfile("MyDefrag.log","LogHeader")
VolumeSelect
CommandlineVolumes()
VolumeActions
AppendLogfile("MyDefrag.log","LogBefore") Thiết lập vùng đầu tiên của bạn
Bằng cách chia bề mặt HDD thành các vùng, MyDefrag cho phép bạn đặt các tệp và thư mục cụ thể trên các phần của bề mặt hoạt động tốt hơn hoặc kém hơn.
Thiết lập các khu vực bằng cách chọn những gì sẽ đến trong chúng:
// Zone 1 - Non-important, slow files FileSelect // Select specific files. !include "file_list.txt"! // Select the files defined in file_list.txt. FileActions // What MyDefrag will do with those files. MoveToEndOfDisk() // Move them to slower portion of the HDD since they are the unimportant ones AddGap(ZoneEnd + VolumeFree * 0.1 // Add a 0.1% size gap between that zone and the next one FileEnd // End file selection for the specific zone
Thiết lập nhiều khu vực hơn
MyDefrag chỉ có thể đóng gói các tệp của bạn lại với nhau, giống như các trình chống phân mảnh khác, nếu bạn không thiết lập bất kỳ Vùng nào, nhưng bạn sẽ bỏ lỡ toàn bộ điểm sử dụng của nó.
Chúng tôi thiết lập thêm các khu vực như sau:
// Zone 2: Put directories together, for quicker listing of the HDD's contents - same syntax as before
FileSelect
Directory(yes) // Define that we want to select directories, not files.
FileActions
SortByName(Ascending) // Sort them by alphabetical order.
AddGap(ZoneEnd + VolumeFree * 0.05)
FileEnd
// Zone 3: Typical, popular "game filetypes", for quicker game launching
FileSelect
Filename("_.exe")
OR Filename("_.dll")
OR Filename("_.ini")
OR Filename("_.conf")
OR Filename("_.cfg")
OR Filename("_.bat")
OR Filename("_.ico")
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree * 0.1)
FileEnd
// Zone 4: Place the MFT and other special NTFS files right after our most important files
FileSelect
SelectNtfsSystemFiles(yes)
FileActions
PlaceNtfsSystemFiles(Ascending,MftSize * 0.01) // Move the selected NTFS system files and set the MFT to a %0.01 size.
AddGap(ZoneEnd + VolumeFree * 0.01)
FileEnd
// Zone 5: Recently accessed files (for better performance of last games played).
FileSelect
LastAccessEnabled(yes) and LastAccess(60 days ago,now)
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree * 0.3)
FileEnd
// Zone 6: all other files.
FileSelect
all
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree)
FileEnd Tập lệnh cuối cùng
Những gì sau đây là toàn bộ kịch bản cuối cùng. Hãy sao chép và dán nó vào tập lệnh của riêng bạn, sau đó chỉnh sửa nó theo ý muốn của bạn.
Title("Make Tech Easier's Games HDD Monthly")
Description("Optimize Game HDDs by moving temp, downloading, and non-important gaming-related files and directories to its end, leaving the faster HDD space for more important stuff.")
// Write the header to the logfile. See the "Settings.MyD" file for the definition of the "LogHeader" string.
WriteLogfile("MyDefrag.log","LogHeader")
// Select and process the volumes one by one.
VolumeSelect
CommandlineVolumes()
VolumeActions
// Write the "before" statistics to the logfile. See the "Settings.MyD" file for the definition of the "LogBefore" string.
AppendLogfile("MyDefrag.log","LogBefore")
// Zone 1 - Place Non-important, temp and ultra-large files at the end of the disk.
FileSelect
!include "file_list.txt"!
FileActions
MoveToEndOfDisk()
AddGap(ZoneEnd + VolumeFree * 0.1)
FileEnd
// Zone 2: Directories.
FileSelect
Directory(yes)
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree * 0.05)
FileEnd
// Zone 3: Main Game Files (for quicker game launch).
FileSelect
Filename("*.exe")
OR Filename("*.dll")
OR Filename("*.ini")
OR Filename("*.conf")
OR Filename("*.cfg")
OR Filename("*.BAT")
OR Filename("*.ico")
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree * 0.1)
FileEnd
//Zone 4: Place the MFT and some other special NTFS files.
FileSelect
SelectNtfsSystemFiles(yes)
FileActions
PlaceNtfsSystemFiles(Ascending,MftSize * 0.01)
AddGap(ZoneEnd + VolumeFree * 0.01)
FileEnd
// Zone 5: Recently accessed files (for better performance of last games played).
FileSelect
LastAccessEnabled(yes) and LastAccess(60 days ago,now)
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree * 0.3)
FileEnd
// Zone 6: all other files.
FileSelect
all
FileActions
SortByName(Ascending)
AddGap(ZoneEnd + VolumeFree)
FileEnd
// Write the "after" statistics to the logfile. See the "Settings.MyD" file for the definition of the "LogAfter" string.
AppendLogfile("MyDefrag.log","LogAfter")
VolumeEnd
// Write the footer to the logfile. See the "Settings.MyD" file for the definition of the "LogFooter" string.
AppendLogfile("MyDefrag.log","LogFooter") Tạo danh sách tệp có mức độ ưu tiên thấp
Hãy nhớ cách chúng tôi đã yêu cầu tập lệnh của mình tính đến danh sách các tệp có mức độ ưu tiên thấp, ở định dạng TXT, trước khi tổ chức các tệp của chúng tôi? Bây giờ là lúc để tạo tệp đó.
Nhấp chuột phải vào thư mục script và tạo một tệp TXT trống, mới. Đặt tên cho nó là “file_list.txt” - cùng một tên tệp mà chúng tôi đã sử dụng trong chính tập lệnh.
Đây là danh sách mẫu bạn có thể sao chép và sử dụng. Thay đổi các thư mục và tệp thành những thư mục mà bạn không quan tâm.
DirectoryName("Game_I_never_play_after_installing")
OR DirectoryName("Another_game_I_keep_but_rarely_play")
OR DirectoryName("Game_that_takes_up_almost_half_the_HDD")
OR Filename("vc_redist.x64.exe")
OR Filename("vcredist_x64.exe")
OR Filename("vcredist_x64*.exe")
OR Filename("*.iso")
OR Filename("*.isz")
OR Filename("*.mdf")
OR Filename("*.cdi")
OR Filename("*.pdf")
OR Filename("*.bik")
OR Filename("*.avi")
OR Filename("*.wmv")
OR Filename("*.bk2")
OR Filename("*.mp4")
OR Filename("*.rar")
OR Filename("*.zip")
OR Filename("*.7z")
OR Filename("*.7z.*") Chạy tập lệnh của bạn
Với hai tệp xác định logic chống phân mảnh của bạn đã sẵn sàng, đã đến lúc thực hiện chúng! Chạy MyDefrag và nếu không có lỗi đánh máy ở bất kỳ đâu, thì tập lệnh của bạn sẽ hiển thị trong số các tập lệnh mặc định trong danh sách của chương trình.
Chọn nó từ danh sách "Chọn một tập lệnh". Sau đó, như MyDefrag nói, “Chọn 1 hoặc nhiều đĩa” từ danh sách thứ hai mà bạn muốn chống phân mảnh dựa trên các quy tắc của tập lệnh của mình. Nhấp vào “Run” và cho nó vài giờ (hoặc vài ngày đối với ổ cứng HDD lớn Terabyte) để nó phát huy tác dụng của nó.
Đó là nó. Bạn đã chống phân mảnh và tối ưu hóa đĩa cứng của mình theo cách bạn muốn và hiện tại nó sẽ hoạt động tốt hơn và nhanh hơn.
Có liên quan:
- Điều gì sẽ xảy ra khi bạn chống phân mảnh ổ đĩa?
- 5 công cụ cải thiện hiệu suất ổ cứng Windows 10
- Cách chống phân mảnh ổ cứng của bạn từ menu ngữ cảnh trong Windows